mirror of
https://github.com/dgibson/dtc.git
synced 2026-01-22 01:30:34 -05:00
9a1c801a1a
It's unsafe to implicitly discard the const qualifier on a pointer. In overlay_fixup_phandle(), this was probably just an oversight, and making the "sep" variable a const char * is sufficient to fix it. In create_node(), however, the "p" variable is directly modifying the buffer pointed to by "const char* node_name". To fix this, we need to actually make a duplicate of the buffer and operate on that instead. This introduces a malloc()/free() and an unbounded strdup() into the operation, but fdtput isn't a long-running service and the node_name argument comes directly from argv, so this shouldn't introduce a significant performance impact. Signed-off-by: Stephen Gallagher <sgallagh@redhat.com> Signed-off-by: David Gibson <david@gibson.dropbear.id.au>
132 lines
2.9 KiB
Meson
132 lines
2.9 KiB
Meson
project('dtc', 'c',
|
|
version: files('VERSION.txt'),
|
|
license: ['GPL2+', 'BSD-2'],
|
|
default_options: ['werror=true', 'default_library=both'],
|
|
meson_version: '>=0.57.0'
|
|
)
|
|
|
|
cc = meson.get_compiler('c')
|
|
|
|
add_project_arguments(
|
|
cc.get_supported_arguments([
|
|
'-Wpointer-arith',
|
|
'-Wcast-qual',
|
|
'-Wnested-externs',
|
|
'-Wstrict-prototypes',
|
|
'-Wmissing-prototypes',
|
|
'-Wredundant-decls',
|
|
'-Wshadow',
|
|
'-Wsuggest-attribute=format',
|
|
'-Wwrite-strings',
|
|
'-Wdiscarded-qualifiers',
|
|
]),
|
|
language: 'c'
|
|
)
|
|
|
|
add_project_arguments(
|
|
'-DFDT_ASSUME_MASK=' + get_option('assume-mask').to_string(),
|
|
language: 'c'
|
|
)
|
|
|
|
yamltree = 'yamltree.c'
|
|
yaml = dependency('yaml-0.1', version: '>=0.2.3', required: get_option('yaml'))
|
|
if not yaml.found()
|
|
add_project_arguments('-DNO_YAML', language: 'c')
|
|
yamltree = []
|
|
endif
|
|
|
|
valgrind = dependency('valgrind', required: get_option('valgrind'))
|
|
if not valgrind.found()
|
|
add_project_arguments('-DNO_VALGRIND', language: 'c')
|
|
endif
|
|
|
|
py = import('python')
|
|
py = py.find_installation(required: get_option('python'))
|
|
swig = find_program('swig', required: get_option('python'))
|
|
pylibfdt_enabled = not meson.is_cross_build() and py.found() and swig.found() ? true : false
|
|
wheel_only = get_option('wheel-only')
|
|
|
|
version_gen_h = vcs_tag(
|
|
command: ['git', 'describe', '--dirty=+'],
|
|
input: 'version_gen.h.in',
|
|
output: 'version_gen.h',
|
|
)
|
|
|
|
subdir('libfdt')
|
|
|
|
dtc_tools = []
|
|
util_dep = declare_dependency(
|
|
sources: ['util.c', version_gen_h],
|
|
include_directories: '.',
|
|
dependencies: libfdt_dep
|
|
)
|
|
|
|
if get_option('tools') and not wheel_only
|
|
flex = find_program('flex', required: true)
|
|
bison = find_program('bison', required: true)
|
|
|
|
lgen = generator(
|
|
flex,
|
|
output: '@PLAINNAME@.lex.c',
|
|
arguments: ['-o', '@OUTPUT@', '@INPUT@'],
|
|
)
|
|
|
|
pgen = generator(
|
|
bison,
|
|
output: ['@BASENAME@.tab.c', '@BASENAME@.tab.h'],
|
|
arguments: ['@INPUT@', '--defines=@OUTPUT1@', '--output=@OUTPUT0@'],
|
|
)
|
|
|
|
if cc.check_header('fnmatch.h')
|
|
dtc_tools += executable(
|
|
'convert-dtsv0',
|
|
[
|
|
lgen.process('convert-dtsv0-lexer.l'),
|
|
'srcpos.c',
|
|
],
|
|
dependencies: util_dep,
|
|
install: true,
|
|
)
|
|
endif
|
|
|
|
dtc_tools += executable(
|
|
'dtc',
|
|
[
|
|
lgen.process('dtc-lexer.l'),
|
|
pgen.process('dtc-parser.y'),
|
|
'checks.c',
|
|
'data.c',
|
|
'dtc.c',
|
|
'flattree.c',
|
|
'fstree.c',
|
|
'livetree.c',
|
|
'srcpos.c',
|
|
'treesource.c',
|
|
yamltree,
|
|
],
|
|
dependencies: [util_dep, yaml],
|
|
install: true,
|
|
)
|
|
|
|
foreach e: ['fdtdump', 'fdtget', 'fdtput', 'fdtoverlay']
|
|
dtc_tools += executable(e, files(e + '.c'), dependencies: util_dep, install: true)
|
|
endforeach
|
|
|
|
install_data(
|
|
'dtdiff',
|
|
install_dir: get_option('bindir'),
|
|
install_mode: 'rwxr-xr-x',
|
|
)
|
|
endif
|
|
|
|
foreach e: dtc_tools
|
|
meson.override_find_program(e.name(), e)
|
|
endforeach
|
|
|
|
if pylibfdt_enabled
|
|
subdir('pylibfdt')
|
|
endif
|
|
|
|
if get_option('tests')
|
|
subdir('tests')
|
|
endif
|