forked from len0rd/rockbox
6b9610fb90
This big commit port qeditor from v1 to v2 register file format. Although the display code was much simplified, the edit code had to be rewritten. The new code also brings many improvement to the register display widget. The new code also compiles with both Qt4 and Qt5, although it is recommended to use Qt5 to get some improvements, especially in the layout of editor. Change-Id: I24633ac37a144f25d9e705b565654269ec9cfbd3
34 lines
993 B
Prolog
34 lines
993 B
Prolog
QT += widgets
|
|
|
|
HEADERS += mainwindow.h backend.h regtab.h analyser.h settings.h \
|
|
std_analysers.h utils.h regdisplaypanel.h regedit.h
|
|
SOURCES += main.cpp mainwindow.cpp regtab.cpp backend.cpp analyser.cpp \
|
|
std_analysers.cpp settings.cpp utils.cpp regdisplaypanel.cpp regedit.cpp
|
|
LIBS += -L../lib/ -lsocdesc -lxml2
|
|
INCLUDEPATH += ../include/ ../../hwstub/lib
|
|
DEPENDPATH += ../
|
|
|
|
libsocdesc.commands = cd ../lib && make
|
|
QMAKE_EXTRA_TARGETS += libsocdesc
|
|
PRE_TARGETDEPS += libsocdesc
|
|
|
|
VERSION = 3.0.0
|
|
|
|
DEFINES += APP_VERSION=\\\"$$VERSION\\\"
|
|
|
|
unix {
|
|
!nohwstub {
|
|
message("Use 'qmake -config nohwstub' if you want to disable hwstub support")
|
|
libhwstub.commands = cd ../../hwstub/lib && make
|
|
QMAKE_EXTRA_TARGETS += libhwstub
|
|
PRE_TARGETDEPS += libhwstub
|
|
|
|
LIBS += -L../../hwstub/lib -lhwstub
|
|
DEPENDPATH += ../../hwstub
|
|
DEFINES += HAVE_HWSTUB
|
|
CONFIG += link_pkgconfig
|
|
PKGCONFIG += libusb-1.0
|
|
}
|
|
}
|
|
|
|
CONFIG += debug
|